Jondolar,

The trial version itself never expires. The applications themselves expire and cannot be used by the trial version if they are more than 30 days old. In this case, the original sample application was built more than 30 days ago, so it will not work with the trial version.

If you want to try this yourself, you can place a command button on the Gem Types form in the the Gems sample app that came with the trial version. Place this code in the On Element Entry event for the command button.

// This routine uses PrintString to create a formatted page including
// information from both the Main record and all of its subrecords.

var vDescription as string
var vPos as int
var vSub as int
var vSubTotal as int
var vPriceTotal as double
var vYCor as int
var vPrice as double
var vSPrice as string

//Create a new Page
NewPage(850,1100)

// Print header
PrintString("Lantica Jewelers", 300, 25, 0, "BArial", 30, 0)

// Format and print Gem_Type, Description and Occurence
vDescription = "The " + Gem_Type + " is " + Description + @NewLine() + "That is most commonly found in "
vDescription = Vdescription + Occurrence
PrintString(vDescription, 50, @PageExtentY() + 10, 725, "Arial", 15, 0)


//Format and print Birthstone and Hardness
vDescription = "It is the birthstone for the month of " + Birthstone_Month + "."
vDescription = vDescription + " It has a Hardness of " + Hardness
PrintString(vDescription, 50, @PageExtentY(), 725, "Arial", 15, 0)

// Print Appearance
PrintString(Appearance, 50, @PageExtentY(), 725, "Arial", 15, 0)

// Print Enhancements
PrintString(Enhancements , 50, @PageExtentY(), 725, "Arial", 15, 0)


// Format and print count of Subrecords.
vDescription = "We at Lantica Jewelers are lucky enough to have " + @FormResultSetTotal("Gems") + " of these rare jewels in stock"
PrintString(vDescription, 50, @PageExtentY() + 10, 725, "Arial", 15, 0)


// Prints Sub Header 1/10 of an inch below the general description of the gem
PrintString("Current Inventory of " + Gem_Type + @NewLine(), 255, @PageExtentY() + 20, 0, "Arial", 25, 0)


//Loops through the Subrecords
vSubTotal = @FormResultSetTotal("Gems")
vSub = 1
While vSub <= vSubTotal
{
	VDescription = @FormFieldValue("Gems", "Gem", vSub)
	vYCor = @PageExtentY() + 2				  // Y coordinate for the values
	FormResultSetCurrentPosition("Gems", vSub)
	PrintString(@FormFieldValue("Gems", "Gem", vSub), 50, vYCor, 90, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Origin", vSub), @PageExtentX() + 1, vYCor, 75, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Shape", vSub), @PageExtentX() + 1, vYCor, 130, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Color", vSub), @PageExtentX() + 1, vYCor, 100, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Size", vSub), @PageExtentX() + 1, vYCor, 100, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Weight", vSub), @PageExtentX() + 1, vYCor, 65, "Arial", 15, 0)
	PrintString(@FormFieldValue("Gems", "Clarity", vSub), @PageExtentX() + 1, vYCor, 90, "Arial", 15, 0)
	vSPrice = @FormFieldValue("Gems", "Price", vSub)
	vPrice = @ToMoney(vSPrice)
	vsPrice = @Decimals(vSPrice, 2)
	PrintString(@Text((9 - @len(vSPrice)) * 2, " ") + "$" + vSPrice , @PageExtentX() + 1, vYCor, 100, "Arial", 15, 0)

	vPriceTotal += vPrice  // Total price being counted up
	vSub = vSub + 1
}
FormResultSetCurrentPosition("Gems", 1)


//List total cost of all gems and finish the page
//Note the following line will need to be changed if a different money symbol other than $ is desired.
PrintString("Total value of Gems listed is: $" + @Decimals(VPriceTotal,2), 50, @PageExtentY() + 20, 0, "Arial", 20, 0)
FinishPage()
 

The code may or may not need some adjustment to work with the trial sample app.

The browsers (all browsers) create their own page breaks and are quite bizarre in that the settings for what appears are stored in the registry! It makes it difficult for us to override them, although we are working on it. An upcoming version will likely allow you to set these options as part of your report design.  Since Sesame reports create a web page, it is all really one "page" until the printer gets ahold of it.

The Page Headers and Page Footers in Sesame reports can be made to appear if you place a Page Break element in a freeform section of your report. They will appear in addition to, rather than overriding the Page Headers and Footers that your browser provides. The concept of Page Headers and Footers does not mesh well with the concept of HTML. If Page Headers and Footers are paramount, you may want to explore the PrintString options.

You'd need to set it up in your browser itself. At this point, we don't have any control over it, although we may in a future release.

jondolar,

Try putting the static text in the "Group Header". This section tends to line up with the "Group Body" columns.

Oh yeah, I forgot about that. I also would like them to repeat at the top of each page.

Serge,

The point of the sample was to demonstrate precision printing and looping through subrecords in SBasic, not to demonstrate the simplest way to create a report.

You can also do this with a report/subreport from the Report Designer, with the exception of Page Headers and Footers.

We traded Page Headers and Footers for the tremendous power and transportability of HTML. HTML can be used and imported by many other programs, such as Word, Access and Excel. HTML reports can be emailed or mounted online without any further processing. They can be interactive (clickable). They automatically adjust themselves to fit on screen or printed page. Etc... Time will tell if Page Headers are so overwhelmingly important to people that all other benefits become irrelevant.

In the end, Sesame does not actually print your report. On Windows the operating system's HTML Printer (an included .dll) actually prints the report. Sesame merely sees it as another document (a file). On Windows the the page header and footer information is stored in your registry(!). Sesame could alter these and then restore them when printing is complete. I've experimented a little with this technique and got it to work. But the user still does not have page by page control over the content, and the content formatting allowed by the OS is very "lightweight". Additionally, I really don't like the idea of altering your registry settings on the fly. On Unix, the printing is done by a html to postscript conversion (producing a file - not a print) that gets sent to the user specified "lp/lpr" device. Here there is some leeway in term of page header and footer specifications - but still not enough.

We have been looking for a good HTML library to parse and print the HTML with callback notification, so that Sesame can intervene and insert page headers and footers, yet not interfere with using the HTML as a "document" as opposed to the printed piece of paper.