Hi folks!

I'm writing a snippet of code to be a mass update to let folks know who is locking a record, and send a quick message to tell them to get out.  However, it's not working.  Code is below.

- the call of the IP works great
- the call of the User works great
- no matter what, I can't get the message to go through with @redirectprocess, or @shell, but the exact same line typed in a command prompt works -- why?

Thanks!

stat vIPLookup as string
stat vIP as string
stat vIPUser as string
stat vIPCommand as string
stat vIPMessage as string
stat vMessage as string

vIPLookup = @PromptForUserInput("Which IP To Look Up?","192.168.2.181")
vIPCommand = @RedirectProcess("nslookup " + vIPLookup,"")
vIPUser = @RedirectPRocess("wmic.exe /node:" + vIPLookup + " computersystem get username","")
@MsgBox(vIPLookup,vIPUser,"")

if @instr(vIPCommand,"ERROR") < 1
{
	if @askuser("Message " + VIPUser + "?","","")
	{
		vIPMessage = @PromptForUserInput("Message?","")
		if vIPMessage <> ""
		{
			vIPCommand = "msg /server:" + vIPLookup + " * " + @chr(34) + vIPMessage + @chr(34)
			vIPCommand = @redirectprocess(vIPCommand,"")
			// vIPCommand = @Shell(vIPCommand)
		}
	}
}
 

Hey Blair,

This one was very tricky. Why you may ask? Well I'll bet my lunch money that your Windows OS is 64bit. Being that the current version of Sesame is 32bit when we make a system call(@Shell() or RedirectProcess()) the OS "knows" to launch what is essentially a 32bit command prompt. Now normally this isn't an issue but in this case the 32bit command prompt can't find msg.exe because Microsoft did not put the 32bit version of it in any directory that is in the PATH variable. Now you may be saying, but I can launch msg.exe from a command prompt. Yes, you can. You're launching the 64bit version of msg.exe with the 64bit command prompt. The solution however is rather simple(Just took a while to find....) we just need to tell Sesame the path to the 32bit msg.exe file. On a 64bit version of Windows(Except perhaps Home versions which may not have the executable), the path is "c:\Windows\sysnative\msg.exe" and on a 32bit Windows OS the path is "c:\Windows\System32\msg.exe".

So something like....

Var vS as String
Var vPath as String

IF FileExists("c:\Windows\sysnative\msg.exe") Then
{
	vPath = "c:\Windows\sysnative\msg.exe"
}
Else
{
	vPath = "c:\Windows\System32\msg.exe"
}

vS = @RedirectProcess(vPath + " * 'My Message'", "") 

-Ray

BWETTLAUFER wrote on Jul 20^th, 2018 at 2:26pm:


You won't see it through explorer. It's a virtual directory.

Try the code I posted in a single record Mass Update in say the sample database Customers.

-Ray

Looks like you are missing a quote mark(I'm assuming you modified your code so that vPath is just the directory and not the full path like in my code). Try:

@redirectprocess(vPath + "msg * /server:192.168.2.181 " +  @chr(34) + "test" + @chr(34),"") 

-Ray

Got it working!  Thanks!

Here's the full code, if anyone else wants to use this.

stat vIPLookup as string
stat vIP as string
stat vIPUser as string
stat vIPCommand as string
stat vIPMessage as string
stat vMessage as string
stat vS as String
stat vPath as String

IF FileExists("c:\Windows\sysnative\msg.exe") Then
{
	vPath = "c:\Windows\sysnative\msg.exe"
}
Else
{
	vPath = "c:\Windows\System32\msg.exe"
}

vIPLookup = @PromptForUserInput("Which IP To Look Up?","192.168.2.181")
vIPCommand = @RedirectProcess("nslookup " + vIPLookup,"")
vIPUser = @RedirectPRocess("wmic.exe /node:" + vIPLookup + " computersystem get username","")
@MsgBox(vIPLookup,vIPUser,"")

if @instr(vIPCommand,"ERROR") < 1
{
	if @askuser("Message " + VIPUser + "?","","")
	{
		vIPMessage = @PromptForUserInput("Message?","")
		if vIPMessage <> ""
		{
			vIPCommand = @redirectprocess(vPath + " /server:" + vIPLookup + " * " + @chr(34) + vIPMessage + @chr(34),"")
		}
	}
}